Funciones del lenguaje (X)
por Luciano Moreno, del departamento de Diseño Web de BJS Software.

Funciones del lenguaje (M).-

* Mid( cadena, inicio [, longitud] )

Función de cadenas. Recibe como argumento principal una cadena, retornando una subcadena de la misma. Maneja los siguientes argumentos:

- cadena: Obligatorio. Es una cadena, variable que la contenga o expresión de cadena válida, de la cual vamos a extraer la subcadena. Si contiene Null, la función retorna Null.

- inicio: Obligatorio. Es un número, variable que lo contenga o expresión numérica válida, que fija la posición del caracter de la cadena madre a partir del que vamos a extraer la subcadena. Si es mayor que el número de caracteres de la cadena madre, la función retorna una cadena de longitud cero, "".

- longitud: Opcional. Es un número, variable que lo contenga o expresión numérica válida, que fija la longitud en caracteres de la subcadena que queremos sacar de la cadena madre. Si se omite o si existen menos caracteres del número especificado por longitud en el texto (incluido el carácter en inicio), se devuelven todos los caracteres desde la posición de inicio hasta el final de la cadena.

Ejemplo:

<script language="VBScript">
    Function Subcadena()
        Dim MiCadena, MiLongitud, MiInicio, MiSubcadena       
        MiCadena=InputBox("Introduce una cadena", "Ejemplo función Mid")
        MiInicio=InputBox("Introduce el numero de inicio", "Ejemplo función Mid")
        MiLongitud=InputBox("Introduce la longitud de la subcadena", "Ejemplo función Mid")
        MiSubcadena=Mid(MiCadena, MiInicio, MiLongitud)   
        MsgBox ("La subcadena es: " & MiSubcadena)
    End Function
</script>
<form>
  <input type="button" value="pulsame" onClick="Subcadena()">
</form>

cuyo resultado es :

* Minute( hora )

Función de fechas. Recibe como argumento cualquier expresión que pueda contener una hora, retornando un número entero entre 0 y 59, inclusive, que representa el minuto de la hora. Si hora contiene Null, retorna Null.

Ejemplo:

<script language="VBScript">
    Function DameMinuto()
        Dim MiMinuto       
        MiMinuto=Minute(Now)
        MsgBox ("El minuto actual es: " & MiMinuto)
    End Function
</script>
<form>
  <input type="button" value="pulsame" onClick="DameMinuto()">
</form>

que nos da:

* Month( fecha )

Función de fechas. Recibe como argumento cualquier expresión que pueda representar una fecha, retornando un número entero entre 1 y 12, inclusive, que representa el mes del año. Si fecha contiene Null, retorna Null.

Ejemplo:

<script language="VBScript">
    Function DameMes()
        Dim MiMes       
        MiMes=Month(Now)
        MsgBox ("El mes actual es: " & MiMes)
    End Function
</script>
<form>
  <input type="button" value="pulsame" onClick="DameMes()">
</form>

del que obtenemos:

* MonthName( mes, [abreviatura] )

Función de fechas. Recibe como argumento un número del 1 al 12, variable que lo contenga o expresión numérica válida, retornando una cadena de texto que indica el mes especificado. Como argumento opcional admite abreviatura, valor de tipo booleano que indica si el nombre del mes debe aparecer abreviado o no. Si se omite, el valor predeterminado es False, que significa que el nombre del mes no aparecerá abreviado.

Ejemplo:

<script language="VBScript">
    Function DameNombre()
        Dim MiMes, MiNombre       
        MiMes=Month(Now)
        MiNombre=MonthName(MiMes)
        MsgBox ("El mes actual es: " & MiNombre)
    End Function
</script>
<form>
  <input type="button" value="pulsame" onClick="DameNombre()">
</form>

que nos da:

* MsgBox( mensaje [, botones, titulo, archivoayuda, contexto] )

Función de llamada a objeto del lenguaje. Muestra un mensaje en un cuadro de diálogo, espera a que el usuario haga clic en un botón y devuelve un valor que indica el botón en el que se hizo clic.

Sus argumentos son:

- mensaje: Obligatorio. Expresión de cadena que define el mensaje que va a aparecer en el cuadro de diálogo. Puede tener una longitud máxima de unos 1024 caracteres (depende del ancho de la fuente utilizada). Si el mensaje es largo y deseamos formatearlo, podemos separar las líneas con un carácter de retorno de carro (Chr(13)), un carácter de nueva línea (Chr(10)) o la combinación de carácter de retorno de carronueva línea (Chr(13) & Chr(10)) entre cada línea.

- botones: Opcional. Número, variable que lo contenga o expresión numérica válida, que es la suma de valores que especifican el número y tipo de botones que se van a mostrar, el estilo de icono que se va a utilizar, la identidad del botón predeterminado y la modalidad del cuadro de mensaje. Los valores posibles son:

constante	valor	descripción
vbOKOnly	0	Muestra sólo el botón Aceptar.
vbOKCancel	1	Muestra los botones Aceptar y Cancelar.
vbAbortRetryIgnore	2	Muestra los botones Anular, Reintentar e Ignorar.
vbYesNoCancel	3	Muestra los botones Sí, No y Cancelar.
vbYesNo	4	Muestra los botones Sí y No.
vbRetryCancel	5	Muestra los botones Reintentar y Cancelar.
vbCritical	16	Muestra el icono Mensaje crítico.
vbQuestion	32	Muestra el icono Consulta de advertencia.
vbExclamation	48	Muestra el icono Mensaje de advertencia.
vbInformation	64	Muestra el icono Mensaje de información.
vbDefaultButton1	0	El primer botón es el predeterminado.
vbDefaultButton2	256	El segundo botón es el predeterminado.
vbDefaultButton3	512	El tercer botón es el predeterminado.
vbDefaultButton4	768	El cuarto botón es el predeterminado.
vbApplicationModal	0	Cuadro de diálogo modal de la aplicación. El usuario debe responder al cuadro de diálogo antes de continuar trabajando en la aplicación actual.
vbSystemModal	4096	Cuadro de diálogo modal del sistema. Se suspenden todas las aplicaciones hasta que el usuario responda al cuadro de mensaje.

El primer grupo de valores (05) describe el número y tipo de botones mostrados en el cuadro de diálogo; el segundo grupo (16, 32, 48, 64) describe el estilo de icono; el tercer grupo (0, 256, 512, 768) determina qué botón es el predeterminado y el cuarto grupo (0, 4096) determina la modalidad del cuadro de mensaje. Si agregamos números para crear un valor final para el argumento botones, debemos utilizar sólo un número para cada grupo.

Si se omite este argumento, su valor predeterminado es 0.

- titulo: Opcional. Expresión de cadena que determina el mensaje que aparecerá en la barra de título del cuadro de diálogo. Si se omite, el nombre de la aplicación se sitúa en la barra de título.

- archivoayuda: Opcional. Expresión de cadena que identifica el archivo de ayuda que se va a utilizar para proporcionar ayuda interactiva para el cuadro de diálogo. Si se proporciona archivoayuda, también se debe proporcionar contexto. No está disponible en plataformas de 16 bits.

- contexto: Opcional. Expresión numérica que identifica el número de contexto de ayuda asignado por el autor de la ayuda para el tema de ayuda apropiado. Si se proporciona contexto, también se debe proporcionar archivoayuda. No está disponible en plataformas de 16 bits.

Cuando se proporcionan archivoayuda y contexto, el usuario puede presionar F1 para ver el tema de ayuda correspondiente al contexto.

Si el cuadro de diálogo muestra un botón Cancelar, presionar la tecla ESC tiene el mismo efecto que hacer clic en Cancelar. Si el cuadro de diálogo contiene un botón Ayuda, se proporciona ayuda interactiva para el cuadro de diálogo. Sin embargo, no se devuelve ningún valor hasta que se haga clic en uno de los otros botones.

Cuando la función MsgBox se utiliza con Microsoft Internet Explorer, el título de cualquier diálogo presentado siempre contiene "VBScript:" para diferenciarlo de los cuadros de diálogo estándar del sistema.

Valores de retorno

La función MsgBox tiene los siguientes valores de retorno:

constante	valor	botón
vbOK	1	Aceptar
vbCancel	2	Cancelar
vbAbort	3	Anular
vbRetry	4	Reintentar
vbIgnore	5	Ignorar
vbYes	6	Sí
vbNo	7	No

Ejemplo:

<script language="VBScript">
    Function Mensaje()
        Dim TuRespuesta       
        TuRespuesta = MsgBox ("Vamos al cine...", 4, "Ejemplo de MsgBox")
        If TuRespuesta=6 Then
            MsgBox "Nos vemos a las 8", , "Has dicho que SI"
        Else
            MsgBox "Vale, otra vez sera", , "Has dicho que NO"
        End If       
    End Function
</script>
<form>
  <input type="button" value="pulsame" onClick="Mensaje()">
</form>

que nos da:

Observa que al escribir la función MsgBox dentro de la estructura If he eliminado los paréntesis; esto es así porque si no el motor VBScript nos da un error, al no poderse usar paréntesis al llamar a una subrutina (MsgBox está actuando como tal). Nota atmbién como he colocado el espacio correspondiente al argumento botones vacío, pero lo he puesto. Si directamente le pasamos mensaje y después titulo, tomará éste como valor para botones, y al ser una cadena nos dará un error en tiempo de ejecución.